import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

group = "dev.fyloz.colorrecipesexplorer"

plugins {
    id("java")
    id("org.jetbrains.kotlin.jvm") version "1.4.30"
    id("org.jetbrains.dokka") version "1.4.20"
    id("org.springframework.boot") version "2.3.4.RELEASE"
    id("org.jetbrains.kotlin.plugin.spring") version "1.4.30"
    id("org.jetbrains.kotlin.plugin.jpa") version "1.4.30"
}

repositories {
    jcenter()
    mavenCentral()

    maven {
        url = uri("https://git.fyloz.dev/api/v4/projects/40/packages/maven")
    }
}

dependencies {
    implementation(platform("org.jetbrains.kotlin:kotlin-bom:1.4.10"))
    implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8:1.4.10")
    implementation("org.jetbrains.kotlin:kotlin-reflect:1.4.10")
    implementation("com.fasterxml.jackson.module:jackson-module-kotlin:2.11.3")
    implementation("javax.xml.bind:jaxb-api:2.3.0")
    implementation("io.jsonwebtoken:jjwt:0.9.1")
    implementation("org.apache.poi:poi-ooxml:4.1.0")
    implementation("org.apache.pdfbox:pdfbox:2.0.4")
    implementation("dev.fyloz.colorrecipesexplorer:database-manager:1.2.0")

    implementation("org.springframework.boot:spring-boot-starter-data-jpa:2.3.4.RELEASE")
    implementation("org.springframework.boot:spring-boot-starter-jdbc:2.3.4.RELEASE")
    implementation("org.springframework.boot:spring-boot-starter-web:2.3.4.RELEASE")
    implementation("org.springframework.boot:spring-boot-starter-validation:2.3.4.RELEASE")
    implementation("org.springframework.boot:spring-boot-starter-security:2.3.4.RELEASE")
    implementation("org.springframework.boot:spring-boot-configuration-processor:2.3.4.RELEASE")
    implementation("org.springframework.boot:spring-boot-devtools:2.3.4.RELEASE")

    testImplementation("org.springframework:spring-test:5.1.6.RELEASE")
    testImplementation("org.mockito:mockito-inline:3.6.0")
    testImplementation("com.nhaarman.mockitokotlin2:mockito-kotlin:2.2.0")
    testImplementation("org.junit.jupiter:junit-jupiter-api:5.3.2")
    testImplementation("io.mockk:mockk:1.10.6")
    testImplementation("org.springframework.boot:spring-boot-starter-test:2.3.4.RELEASE")
    testImplementation("org.springframework.boot:spring-boot-test-autoconfigure:2.3.4.RELEASE")
    testImplementation("org.jetbrains.kotlin:kotlin-test:1.4.10")
    testImplementation("org.jetbrains.kotlin:kotlin-test-junit:1.4.10")

    runtimeOnly("com.h2database:h2:1.4.199")
    runtimeOnly("mysql:mysql-connector-java:8.0.22")
    runtimeOnly("org.postgresql:postgresql:42.2.16")
    runtimeOnly("com.microsoft.sqlserver:mssql-jdbc:9.2.1.jre11")
}

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

sourceSets {
    main {
        java
        kotlin
    }
    test {
        kotlin
    }
}

tasks.test {
    reports {
        junitXml.isEnabled = true
        html.isEnabled = false
    }

    useJUnitPlatform()
    testLogging {
        events("skipped", "failed")
    }
}

tasks.withType<JavaCompile>() {
    options.compilerArgs.addAll(arrayOf("--release", "11"))
}
tasks.withType<KotlinCompile>().all {
    kotlinOptions {
        jvmTarget = JavaVersion.VERSION_11.toString()
        useIR = true
        freeCompilerArgs = listOf(
          "-Xopt-in=kotlin.contracts.ExperimentalContracts",
          "-Xinline-classes"
        )
    }
}

tasks.dokkaHtml {
    outputDirectory.set(rootDir.resolve("dokka"))
}